
 1000  *SAVE S.RAMFILL PUTNEY
 1010  *--------------------------------
 1020  *  BY  CHARLES H. PUTNEY
 1030  *      18 QUINNS ROAD
 1040  *      SHANKILL
 1050  *      CO. DUBLIN
 1060  *      IRELAND
 1070  *--------------------------------
 1080         .OR $803     NORMAL PLACE
 1090  *--------------------------------
 1100  PNTR   .EQ $06      BLOCK MOVE POINTER
 1110  *--------------------------------
 1120  KEYBD  .EQ $C000    KEYBOARD DATA
 1130  KEYSTB .EQ $C010    KEYBOARD STROBE
 1140  VIDOUT .EQ $FDF0    VIDEO OUTPUT ROUTINE
 1150  CROUT  .EQ $FD8E    SEND A RETURN
 1160  *--------------------------------
 1170  WIPE   JSR CROUT    START A NEW LINE
 1180         LDX #$00
 1190  .1     LDA MESS,X   TELL HIM WHAT KEY TO PUSH
 1200         JSR VIDOUT   SEND IT
 1210         INX          NEXT CHAR
 1220         TAY          CHECK IF LAST ONE
 1230         BMI .1       NO
 1240         JSR CROUT    SEND A RETURN
 1250         LDX #$00
 1260  .2     LDA IMAGE,X  RELOCATE CODE TO PAGE ONE
 1270         STA $200-CODEND+CODE,X
 1280         INX
 1290         CPX #CODEND-CODE  
 1300         BNE .2
 1310  .3     BIT KEYBD    KEY PRESSED ?
 1320         BPL .3       WAIT UNTIL PUSHED ?
 1330         LDA KEYSTB   RESET STROBE
 1340         LDA KEYBD    MAKE SURE ITS THE RIGHT KEY
 1350         CMP #$4C     IS IT L ? (JMP OPCODE)
 1360         BNE WIPE     TELL HIM AGAIN
 1370         JMP CODE     WIPE OUT !
 1380  *--------------------------------
 1390  *   THIS CODE IS RELOCATED TO PAGE ONE
 1400  *--------------------------------
 1410  IMAGE  .PH $1E1
 1420  CODE   LDA #$00     INITIALIZE POINTER
 1430         STA PNTR
 1440         LDA #$02
 1450         STA PNTR+1   START AT PAGE TWO
 1460         LDA #$48     GET A PHA OPCODE
 1470         LDY #$00     INIT Y REG
 1480  .1     STA (PNTR),Y SAVE PHA OPCODE
 1490         INY          NEXT
 1500         BNE .1       FULL PAGE DONE ?
 1510         INC PNTR+1   NEXT PAGE
 1520         LDX PNTR+1   CHECK IF DONE
 1530         CPX #$C0     AT I/O AREA ?
 1540         BNE .1       NOT YET
 1550  .2     STA $00,Y    SET PAGE ZERO TO $48
 1560         INY          NEXT
 1570         BNE .2       FULL PAGE WIPED ?
 1580  *   FALL INTO PAGE 2 PHA'S
 1590  CODEND .EP
 1600  *--------------------------------
 1610  MESS   .AT -/TYPE UPPER CASE L TO SET MEMORY TO $48  /
 1620  *--------------------------------

